洛谷1098 字符串的展开 解题报告

洛谷1098 字符串的展开

本题地址： http://www.luogu.org/problem/show?pid=1098

题目描述

在初赛普及组的“阅读程序写结果”的问题中，我们曾给出一个字符串展开的例子：如果在输入的字符串中，含有类似于“d-h”或者“4-8”的字串，我们就把它当作一种简写，输出时，用连续递增的字母获数字串替代其中的减号，即，将上面两个子串分别输出为“defgh”和“45678”。在本题中，我们通过增加一些参数的设置，使字符串的展开更为灵活。具体约定如下：
(1) 遇到下面的情况需要做字符串的展开：在输入的字符串中，出现了减号“-”，减号两侧同为小写字母或同为数字，且按照ASCII码的顺序，减号右边的字符严格大于左边的字符。
(2) 参数p1：展开方式。p1=1时，对于字母子串，填充小写字母；p1=2时，对于字母子串，填充大写字母。这两种情况下数字子串的填充方式相同。p1=3时，不论是字母子串还是数字字串，都用与要填充的字母个数相同的星号“*”来填充。
(3) 参数p2：填充字符的重复个数。p2=k表示同一个字符要连续填充k个。例如，当p2=3时，子串“d-h”应扩展为“deeefffgggh”。减号两边的字符不变。
(4) 参数p3：是否改为逆序：p3=1表示维持原来顺序，p3=2表示采用逆序输出，注意这时候仍然不包括减号两端的字符。例如当p1=1、p2=2、p3=2时，子串“d-h”应扩展为“dggffeeh”。
(5) 如果减号右边的字符恰好是左边字符的后继，只删除中间的减号，例如：“d-e”应输出为“de”，“3-4”应输出为“34”。如果减号右边的字符按照ASCII码的顺序小于或等于左边字符，输出时，要保留中间的减号，例如：“d-d”应输出为“d-d”，“3-1”应输出为“3-1”。

输入输出格式

输入格式：

输入文件expand.in包括两行：
第1行为用空格隔开的3个正整数，一次表示参数p1，p2，p3。
第2行为一行字符串，仅由数字、小写字母和减号“-”组成。行首和行末均无空格。

输出格式：

输出文件expand.out只有一行，为展开后的字符串。

输入输出样例

输入样例#1：

【输入样例1】
1 2 1
abcs-w1234-9s-4zz
【输入样例2】
2 3 2
a-d-d

输出样例#1：

【输出样例1】
abcsttuuvvw1234556677889s-4zz
【输出样例2】
aCCCBBBd-d

说明

40%的数据满足：字符串长度不超过5
100%的数据满足：1<=p1<=3，1<=p2<=8，1<=p3<=2。字符串长度不超过100
NOIP 2007 提高第二题

题解

模拟+字符串

又是一道纯模拟题。根据题意将合法的“-”展开，注意字符-数字、数字-字符、字符大小写"-"前后相同以及“-”开头的情况。

题目比较繁琐，更多的特殊情况以及细节问题我就不再多说（具体参见代码）。

值得一提的是笔者在字符串操作中用到了与ASCII码有关的的ord和chr函数，这在字符串操作问题上是非常有效的（剩下的靠毅力吧）。

下面附上代码。

代码

program expand;
var
  p1,p2,p3,l,i,j,k:longint;
  s:string;
  a:array[1..100] of longint;
begin
  readln(p1,p2,p3);
  readln(s);
  l:=length(s);
  for i:=1 to l do
    a[i]:=ord(s[i]);
  write(s[1]);
  for i:=2 to l-1 do
    if a[i]=45 then
      begin
        if (a[i-1]=a[i]) or (a[i]=a[i+1]) then
          begin
            write(s[i]);
            continue;
          end;
        if a[i-1]+1=a[i+1] then continue;
        if (a[i-1]+1<a[i+1]) and ((96<a[i-1]) or (a[i+1]<58)) then
          begin
            if (p1=1) and (a[i-1]>96) then
              begin
                if p3=1 then
                for j:=a[i-1]+1 to a[i+1]-1 do
                  for k:=1 to p2 do
                    write(chr(j));
                if p3=2 then
                for j:=a[i+1]-1 downto a[i-1]+1 do
                  for k:=1 to p2 do
                    write(chr(j));
              end;
            if (p1=2) and (a[i-1]>96) then
              begin
                if p3=1 then
                for j:=a[i-1]+1 to a[i+1]-1 do
                  for k:=1 to p2 do
                    write(chr(j-32));
                if p3=2 then
                for j:=a[i+1]-1 downto a[i-1]+1 do
                  for k:=1 to p2 do
                    write(chr(j-32));
              end;
            if ((p1=1) or (p1=2)) and (a[i-1]<96) then
              begin
                if p3=1 then
                for j:=a[i-1]+1 to a[i+1]-1 do
                  for k:=1 to p2 do
                    write(chr(j));
                if p3=2 then
                for j:=a[i+1]-1 downto a[i-1]+1 do
                  for k:=1 to p2 do
                    write(chr(j));
              end;
            if p1=3 then
              for j:=a[i+1]-1 downto a[i-1]+1 do
                for k:=1 to p2 do
                  write('*');
          end
        else write(s[i]);
      end
    else write(s[i]);
  write(s[l]);
end.

（本文系笔者原创，未经允许不得转载）