flash自定义右键菜单

var myContextMenu:ContextMenu = new ContextMenu();
//声明菜单新项
var item:ContextMenuItem = new ContextMenuItem("Hello World");
//添加到菜单显示项目数组
myContextMenu.customItems.push(item);
this.contextMenu = myContextMenu;

//点击按钮引发该事件
item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, mouseRelease);

function mouseRelease(event:ContextMenuEvent)
{
    var txtField:TextField = new TextField();
    txtField.text = "Hello World";
    addChild(txtField);
}

//扩展类ContextMenuPlus

package com.util
{
    import flash.events.ContextMenuEvent;
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.ui.ContextMenuItem;

    public class ContextMenuPlus
    {
        private var _contextMenu:ContextMenu;

        /**
         * @param removeAll 是否禁用所有默认菜单
         * @param listener 自定义菜单事件句柄
         * @param customItems 自定义标签，可以是一个数组
         */
        public function ContextMenuPlus(removeAll:Boolean = true, listener:Function = null,  customItems)
        {
            _contextMenu = new ContextMenu();
            if (removeAll)
            {
                removeDefault();
            }
            if (customItems.length > 0 && listener != null)
            {
                addCustomItems(listener, customItems);
            }
        }

        public function get contextMenu():ContextMenu
        {
            return _contextMenu;
        }

        public function get builtInItems():ContextMenuBuiltInItems
        {
            return _contextMenu.builtInItems;
        }
        /**
         * 禁用默认菜单
         * @param leave 保留默认菜单(标签数组)
         */
        public function removeDefault( leave):void
        {
            _contextMenu.hideBuiltInItems();
            if (leave.length == 0)
            {
                return;
            }
            var defaultItems:ContextMenuBuiltInItems = _contextMenu.builtInItems;
            for each (var item:String in leave)
            {
                defaultItems[item] = true;
            }
        }

        /**
         * 添加自定义菜单项
         * @param caption 菜单项标题
         * @param listener 事件句柄
         * @param separatorBefore 是否在菜单上方添加分割线
         * @param enabled 是否可用
         * @param visible 是否可见
         */
        public function addCustom(listener:Function, caption:String, separatorBefore:Boolean = false, enabled:Boolean = true, visible:Boolean = true):void
        {
            var item:ContextMenuItem = new ContextMenuItem(caption, separatorBefore, enabled, visible);
            _contextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_Select, listener);
        }

        /**
         * 添加自定义菜单组，所有菜单项共用同一个事件句柄
         * 通过 event.currentTarget.caption 区分不同的菜单项
         * private function onSelect(event:ContextMenuEvent):void{
         * var item:ContextMenuItem = event.currentTarget;
         * switch(item.caption)}
         * @param listener 事件句柄
         * @param separatorBefore 是否在菜单组上方添加分隔线
         * @param customItems 菜单项标题，可以是一个数组
         */
        public function addGroup(listener:Function, separatorBefore:Boolean = false,  customItems):void
        {
            addCustomItems(listener, customItems, separatorBefore);
        }
        private function addCustomItems(listener:Function, customItems:Array, separatorBefore:Boolean = false):void
        {
            var itemArr:Array = customItems.length == 1 && customItems[0] is Array ? customItems[0] : customItems;
            for each (var caption:String in itemArr)
            {
                addCustom(listener, caption, separatorBefore);
                if (separatorBefore)
                {
                    separatorBefore = false;
                }
            }
        }
    }
}

//测试类:TestContextMenu

package com.util
{
    import flash.display.Sprite;
    import flash.events.ContextMenuEvent;
    import flash.text.TextField;
    import flash.ui.ContextMenuItem;
    import com.util.ContextMenuPlus;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;

    public class TestContextMenu extends Sprite
    {
        private var txt:TextField;
        private var answerObj:Object = new Object();
        private var txtColorObj:Object = new Object();
        private var borderColorObj:Object = new Object();

        public function TestContextMenu()
        {
            initTxt();
            initObj();
            initCm();
        }

        private function initTxt():void
        {
            txt = new TextField();
            txt.text = "ok";
            txt.width = 200;
            txt.x = 50;
            txt.y = 20;
            txt.border = true;
            txt.borderColor = 0x006699;
            txt.height = 60;
            txt.wordWrap = true;
            this.addChild(txt);

        }

        private function initObj():void
        {
            answerObj["母亲节是哪天？"] = "五月的第二个星期日";
            answerObj["父亲节是哪天？"] = "六月的第三个星期日";
            txtColorObj["红色文字"] = 0xFF0000;
            txtColorObj["蓝色文字"] = 0x0000FF;
            txtColorObj["黑色文字"] = 0x000000;
            borderColorObj["绿色边框"] = 0x00FF00;
            borderColorObj["紫色边框"] = 0x8000FF;
            borderColorObj["黑色边框"] = 0x000000;
        }

        private function initCm():void
        {
            var cm:ContextMenuPlus = new ContextMenuPlus(true, onShowAnswer, "母亲节是哪天？", "父亲节是哪天？");
            contextMenu = cm.contextMenu;
            cm.addCustom(onGetUrl, "eidiot's blog", true);
            cm.addGroup(onSetBorderColor, true, "绿色边框", "紫色边框", "黑色边框");
            
            txt.contextMenu = new ContextMenuPlus(true, onSetTxtColor, "红色文字", "蓝色文字", "黑色文字").contextMenu;
        }

        private function onShowAnswer(e:ContextMenuEvent):void
        {
            txt.text = "问 : " + e.currentTarget.caption + " \t答 : " + answerObj[e.currentTarget.caption];
        }

        private function onSetTxtColor(e:ContextMenuEvent):void
        {
            txt.textColor = txtColorObj[e.currentTarget.caption];
        }

        private function onSetBorderColor(e:ContextMenuEvent):void
        {
            txt.borderColor = borderColorObj[e.currentTarget.caption];
        }

        private function onGetUrl(e:ContextMenuEvent):void
        {
            navigateToURL(new URLRequest("http://eidiot.net"), "_blank");
        }
    }
}