域名批量查询功能实现思路

<%
On Error Resume Next
Server.ScriptTimeOut=9999999

action=Request.QueryString("action")

Function getHTTPPage(Path)
         t = GetBody(Path)
         getHTTPPage=BytesToBstr(t,"GB2312")
End function
Function CleanHtml(str)
Dim RegEx
Set RegEx = New RegExp
RegEx.Pattern = "<\/*[^<>]*>|{\/*[^{}]*>"
RegEx.Global = True
CleanHtml = RegEx.Replace(str, "")
End Function
Function GetBody(url)
on error resume next
Set Retrieval = CreateObject("Microsoft.XMLHTTP")
With Retrieval
   .Open "Get", url, False, "", ""
   .Send
   GetBody = .ResponseBody
End With
Set Retrieval = Nothing
End Function
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb."&"stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function

If action="do" then
domain = trim(Request.Form("domain"))
root = trim(Request.Form("root"))
If Len(domain)=0 Or Len(root)=0 Then
Response.Write "两者不能为空"
Response.End()
End If

domain = Replace(domain,"'","")
root = Replace(root,"'","")
arrRoot=Split(root,",")
body=""

For i=0 To ubound(arrRoot)'进行多个域名后缀查询时通过循环进行列表查询
   url="http://panda.www.net.cn/cgi-bin/Check.cgi?domain="&trim(domain)&"&ext="&trim(arrRoot(i))
   sDomain=trim(domain)&"."&trim(arrRoot(i))

   wstr=CleanHtml(getHTTPPage(url))

   If instr(lcase(wstr),"已经被注册")>0 then
    body=body&"<a href=whois.asp?domain="&sDomain&" target='new' title='点击查看该域名的WHOIS'>域名 "&sDomain&" 已经被注册，点击查看WHOIS</a><br>"
   Elseif instr(lcase(wstr),"没有被注册")>0 then
    body=body&"<a href='Domainregister.asp?domain="+sDomain+"' target='new' title='点击注册该域名'>域名 "&sDomain&" 未被注册，点击注册该域名</a><br>"
   Else
    body=body&"域名 "&sDomain&" 查询超时,请重新查找<br>"
   End If
   'Response.Write "<textarea rows='4' style='80%'>"&wstr&"</textarea><br>"&sDomain&"<br>"&body&"<br>"
Next
%>

<table border="0" width="550" cellspacing="0" cellpadding="0" align=center>
   <tr bgcolor="#EFEFEF">
    <td height="30"><strong>域名查询结果：</strong></td>
   </tr>
   <tr>
    <td style="padding-left:20px;line-height:200%;">
      <%
      if body="" then
       response.write "域名查询有错误！"
      Else
       response.write body
      end If
      %>
    </td>
   </tr>
</table><br>
<%End If%>