异常错误处理

一异常处理的概念

异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.

有三种类型的异常错误：

1．预定义 ( Predefined )错误

　　 ORACLE预定义的异常情况大约有24个。对这种异常情况的处理，无需在程序中定义，由ORACLE自动将其引发。

2．非预定义 ( Predefined )错误

　　即其他标准的ORACLE错误。对这种异常情况的处理，需要用户在程序中定义，然后由ORACLE自动将其引发。

3．用户定义(User_define) 错误

　　程序执行过程中，出现编程人员认为的非正常情况。对这种异常情况的处理，需要用户在程序中定义，然后显式地在程序中将其引发。

异常处理部分一般放在 PL/SQL 程序体的后半部,结构为:

EXCEPTION
   WHEN first_exception THEN  <code to handle first exception >
   WHEN second_exception THEN  <code to handle second exception >
   WHEN OTHERS THEN  <code to handle others exception >
END;

异常处理可以按任意次序排列,但 OTHERS 必须放在最后.

1 预定义错误的异常处理

错误号	异常错误信息名称	说明
ORA-0001	Dup_val_on_index	违反了唯一性限制
ORA-0051	Timeout-on-resource	在等待资源时发生超时
ORA-0061	Transaction-backed-out	由于发生死锁事务被撤消
ORA-1001	Invalid-CURSOR	试图使用一个无效的游标
ORA-1012	Not-logged-on	没有连接到ORACLE
ORA-1017	Login-denied	无效的用户名/口令
ORA-1403	No_data_found	SELECT INTO没有找到数据
ORA-1422	Too_many_rows	SELECT INTO 返回多行
ORA-1476	Zero-divide	试图被零除
ORA-1722	Invalid-NUMBER	转换一个数字失败
ORA-6500	Storage-error	内存不够引发的内部错误
ORA-6501	Program-error	内部错误
ORA-6502	Value-error	转换或截断错误
ORA-6504	Rowtype-mismatch	宿主游标变量与 PL/SQL变量有不兼容行类型
ORA-6511	CURSOR-already-OPEN	试图打开一个已处于打开状态的游标
ORA-6530	Access-INTO-null	试图为null 对象的属性赋值
ORA-6531	Collection-is-null	试图将Exists 以外的集合( collection)方法应用于一个null pl/sql 表上或varray上
ORA-6532	Subscript-outside-limit	对嵌套或varray索引得引用超出声明范围以外
ORA-6533	Subscript-beyond-count	对嵌套或varray 索引得引用大于集合中元素的个数.

对这种异常情况的处理，只需在PL/SQL块的异常处理部分，直接引用相应的异常情况名，并对其完成相应的异常错误处理即可。

例子：

更新指定员工工资，如工资小于1500，则加100；

 1 DECLARE
 2    v_empno employees.employee_id%TYPE := &empno;
 3    v_sal   employees.salary%TYPE;
 4 BEGIN
 5    SELECT salary INTO v_sal FROM employees WHERE employee_id = v_empno;
 6    IF v_sal<=1500 THEN 
 7         UPDATE employees SET salary = salary + 100 WHERE employee_id=v_empno; 
 8         DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已更新!');     
 9    ELSE
10         DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已经超过规定值!');
11    END IF;
12 EXCEPTION
13    WHEN NO_DATA_FOUND THEN  
14       DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||v_empno||'的员工');
15    WHEN TOO_MANY_ROWS THEN
16       DBMS_OUTPUT.PUT_LINE('程序运行错误!请使用游标');
17    WHEN OTHERS THEN
18       DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
19 END;

2 非预定义错误的异常处理

对于这类异常情况的处理，首先必须对非定义的ORACLE错误进行定义。步骤如下：

1.在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

2. 将其定义好的异常情况，与标准的ORACLE错误联系起来，使用EXCEPTION_INIT语句：

PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>);

例子：删除指定部门的记录信息，以确保该部门没有员工。

 1 INSERT INTO departments VALUES(50, 'FINANCE', 'CHICAGO');
 2 
 3 DECLARE
 4    v_deptno departments.department_id%TYPE := &deptno;
 5    deptno_remaining EXCEPTION;
 6    PRAGMA EXCEPTION_INIT(deptno_remaining, -2292);
 7    /* -2292 是违反一致性约束的错误代码 */
 8 BEGIN
 9    DELETE FROM departments WHERE department_id = v_deptno;
10 EXCEPTION
11    WHEN deptno_remaining THEN 
12       DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!');
13    WHEN OTHERS THEN
14       DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
15 END;

3 用户自定义的异常处理

当与一个异常错误相关的错误出现时，就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时，控制就转向到 EXCEPTION块异常错误部分，执行错误处理代码。

对于这类异常情况的处理，步骤如下：

1．在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

2． RAISE <异常情况>；

3．在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例子：更新指定员工工资，增加100；

 1 DECLARE
 2    v_empno employees.employee_id%TYPE :=&empno;
 3    no_result  EXCEPTION;
 4 BEGIN
 5    UPDATE employees SET salary = salary+100 WHERE employee_id = v_empno;
 6    IF SQL%NOTFOUND THEN
 7       RAISE no_result;
 8    END IF;
 9 EXCEPTION
10    WHEN no_result THEN 
11       DBMS_OUTPUT.PUT_LINE('你的数据更新语句失败了!');
12    WHEN OTHERS THEN
13       DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
14 END;

4 用户定义的异常处理

调用DBMS_STANDARD(ORACLE提供的包)包所定义的RAISE_APPLICATION_ERROR过程，可以重新定义异常错误消息，它为应用程序提供了一种与ORACLE交互的方法。

RAISE_APPLICATION_ERROR的语法如下：

RAISE_APPLICATION_ERROR(error_number,error_message,[keep_errors] );

这里的error_number 是从 –20,000 到 –20,999 之间的参数，error_message 是相应的提示信息(< 2048 字节)。keep_errors 为可选，如果keep_errors =TRUE ,则新错误将被添加到已经引发的错误列表中。如果keep_errors=FALSE(缺省),则新错误将替换当前的错误列表。

例子：

创建一个函数get_salary, 该函数检索指定部门的工资总和，其中定义了-20991和-20992号错误，分别处理参数为空和非法部门代码两种错误：

 1 CREATE TABLE errlog(
 2   Errcode NUMBER,
 3   Errtext CHAR(40));
 4 
 5 CREATE OR REPLACE FUNCTION get_salary(p_deptno NUMBER)
 6 RETURN NUMBER 
 7 AS
 8   v_sal NUMBER;
 9 BEGIN
10   IF p_deptno IS NULL THEN
11     RAISE_APPLICATION_ERROR(-20991, ’部门代码为空’);
12   ELSIF p_deptno<0 THEN
13     RAISE_APPLICATION_ERROR(-20992, ’无效的部门代码’);
14   ELSE
15     SELECT SUM(employees.salary) INTO v_sal FROM employees 
16     WHERE employees.department_id=p_deptno;
17     RETURN v_sal;
18   END IF;
19 END;
20 
21 DECLARE 
22   V_salary NUMBER(7,2);
23   V_sqlcode NUMBER;
24   V_sqlerr VARCHAR2(512);
25   Null_deptno EXCEPTION;
26   Invalid_deptno EXCEPTION;
27   PRAGMA EXCEPTION_INIT(null_deptno,-20991);
28   PRAGMA EXCEPTION_INIT(invalid_deptno, -20992);
29 BEGIN
30   V_salary :=get_salary(10);
31   DBMS_OUTPUT.PUT_LINE('10号部门工资：' || TO_CHAR(V_salary));
32 
33   BEGIN
34     V_salary :=get_salary(-10);
35   EXCEPTION
36     WHEN invalid_deptno THEN
37       V_sqlcode :=SQLCODE;
38       V_sqlerr  :=SQLERRM;
39       INSERT INTO errlog(errcode, errtext) 
40       VALUES(v_sqlcode, v_sqlerr);
41       COMMIT;
42   END inner1;
43 
44   V_salary :=get_salary(20);
45   DBMS_OUTPUT.PUT_LINE('部门号为20的工资为：'||TO_CHAR(V_salary));
46 
47   BEGIN
48     V_salary :=get_salary(NULL);
49   END inner2;
50 
51   V_salary := get_salary(30);
52   DBMS_OUTPUT.PUT_LINE('部门号为30的工资为：'||TO_CHAR(V_salary));
53 
54   EXCEPTION
55     WHEN null_deptno THEN
56       V_sqlcode :=SQLCODE;
57       V_sqlerr  :=SQLERRM;
58       INSERT INTO errlog(errcode, errtext) VALUES(v_sqlcode, v_sqlerr);
59       COMMIT;
60     WHEN OTHERS THEN
61          DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
62 END outer;

定义触发器，使用RAISE_APPLICATION_ERROR阻止没有员工姓名的新员式记录插入：

1 CREATE OR REPLACE TRIGGER tr_insert_emp
2 BEFORE INSERT ON employees
3 FOR EACH ROW
4 BEGIN
5   IF :new.first_name IS NULL OR :new.last_name is null THEN
6     RAISE_APPLICATION_ERROR(-20000,'Employee must have a name.');
7   END IF;
8 END;

二异常错误传播

由于异常错误可以在声明部分和执行部分以及异常错误部分出现，因而在不同部分引发的异常错误也不一样。

1 在执行部分引发异常错误。

2 在声明部分引发异常错误

如果在声明部分引起异常情况，即在声明部分出现错误，那么该错误就能影响到其它的块。比如在有如下的PL/SQL程序：

1 DECLARE
2     Abc number(3)=’abc’; 3     其它语句
4 BEGIN
5     其它语句
6 EXCEPTION
7     WHEN OTHERS THEN 
8     其它语句
9 END;

例子中，由于Abc number(3)=’abc’; 出错，尽管在EXCEPTION中说明了WHEN OTHERS THEN语句，但WHEN OTHERS THEN也不会被执行。但是如果在该错误语句块的外部有一个异常错误，则该错误能被抓住，如：

 1 BEGIN
 2     DECLARE
 3     name varchar2(12):='EricHu';
 4     其它语句
 5    BEGIN
 6     其它语句
 7    EXCEPTION
 8     WHEN OTHERS THEN 
 9     其它语句
10     END;
11 EXCEPTION
12 WHEN OTHERS THEN 
13     其它语句
14 END;