poj1088

这题是dp还是dfs+记忆化？（其实好像没什么区别？）

用f[i,j]表示滑到(i,j)时之后最多能滑多远，依次穷举每一个起点(i,j)则

f[i,j]=max{f[i,j-1],f[i-1,j],f[i+1,j],f[i,j+1]}+1 （当然滑到那个点的高度要小于(i,j)的高度）

const dx:array[1..4] of integer=(0,0,-1,1);
      dy:array[1..4] of integer=(-1,1,0,0);
var f,a:array[0..600,0..600] of longint;
    n,i,j,m,ans:longint;
function max(a,b:longint):longint;
  begin
    if a>b then max:=a else max:=b;
  end;
procedure search(x,y:longint);
  var i,xx,yy:integer;
      maxx:longint;
  begin
    maxx:=0;
    for i:=1 to 4 do
    begin
      xx:=x+dx[i];
      yy:=y+dy[i];
      if (a[xx,yy]<a[x,y]) and (f[xx,yy]=0) then search(xx,yy);
      if (a[xx,yy]<a[x,y]) then maxx:=max(maxx,f[xx,yy]);
    end;
    f[x,y]:=maxx+1;
  end;

begin
  readln(n,m);
  for i:=0 to n+1 do
    for j:=0 to m+1 do
      a[i,j]:=21474836;
  for i:=1 to n do
  begin
    for j:=1 to m do
      read(a[i,j]);
    readln;
  end;
  for i:=1 to n  do
    for j:=1 to m do
      if f[i,j]=0 then search(i,j);
  for i:=1 to n do
    for j:=1 to m do
      ans:=max(ans,f[i,j]);
  writeln(ans);
end.