SqlServer try catch 捕获不到的一些错误及解决方法

  1. IF (OBJECT_ID('AA','U') IS NOT NULL)  
  2. DROP TABLE AA  
  3. CREATE TABLE AA(ID INT)  
  4.   
  5. SELECT * FROM AA  
  6.   
  7. --注：数据库当前只存在表AA，无表#BB和表BB  
  8.   
  9. -----------------------------------------------------  
  10. -----------------------------------------------------  
  11.   
  12. --  【案例1】  
  13. BEGIN TRAN   
  14. BEGIN TRY  
  15.     INSERT INTO AA SELECT 1     --A处  
  16.     INSERT INTO #BB SELECT 1    --B处  
  17.     COMMIT TRAN;  
  18. END TRY  
  19. BEGIN CATCH  
  20.     SELECT ERROR_MESSAGE() AS ErrorMessage  
  21.     ,ERROR_SEVERITY() AS ErrorSeverity  
  22.     ,ERROR_STATE() AS ErrorState  
  23.     ROLLBACK TRAN;  
  24. END CATCH  
  25.   
  26. /*运行结果:  
  27.   
  28. (1 行受影响)  
  29. 消息 208，级别 16，状态 0，第 4 行  
  30. 对象名 '#BB' 无效。  
  31.   
  32.   
  33. 说明:A处已经执行;B处中断操作,下面语句未执行  
  34.     查询表AA已经有数据,此时可手动继续操作提交或回滚  
  35. */  
  36.   
  37. -----------------------------------------------------  
  38. -----------------------------------------------------  
  39. --  【案例2】  
  40. BEGIN TRAN   
  41. BEGIN TRY  
  42.     INSERT INTO AA SELECT 1     --A处  
  43.     INSERT INTO BB SELECT 1     --B处  
  44.     COMMIT TRAN;  
  45. END TRY  
  46. BEGIN CATCH  
  47.     SELECT ERROR_MESSAGE() AS ErrorMessage  
  48.     ,ERROR_SEVERITY() AS ErrorSeverity  
  49.     ,ERROR_STATE() AS ErrorState  
  50.     ROLLBACK TRAN;  
  51. END CATCH  
  52.   
  53. /*运行结果:  
  54. 注意：【案例1】使用临时表#BB，【案例2】使用表BB  
  55.   
  56.   
  57. 选中代码执行两次，结果不一样！  
  58.   
  59. 第一次执行结果（不捕获异常），同【案例1】：  
  60.   
  61. (1 行受影响)  
  62. 消息 208，级别 16，状态 0，第 4 行  
  63. 对象名 '#BB' 无效。  
  64.   
  65.   
  66. 第二次执行结果（捕获异常）：  
  67. ErrorMessage    ErrorSeverity   ErrorState  
  68. 对象名 'BB' 无效。    16          1  
  69.   
  70.   
  71. */  
  72. -----------------------------------------------------  
  73. -----------------------------------------------------  
  74.   
  75. --  【案例3】  
  76. BEGIN TRAN   
  77. BEGIN TRY  
  78.     INSERT INTO AA SELECT 1     --A处  
  79.     INSERT INTO AA SELECT 'kk'  --B处  
  80.     COMMIT TRAN;  
  81. END TRY  
  82. BEGIN CATCH  
  83.     SELECT ERROR_MESSAGE() AS ErrorMessage  
  84.     ,ERROR_SEVERITY() AS ErrorSeverity  
  85.     ,ERROR_STATE() AS ErrorState  
  86.     ROLLBACK TRAN;  
  87. END CATCH  
  88.   
  89. /*运行结果（正常捕获异常）：  
  90.   
  91. ErrorMessage                                ErrorSeverity   ErrorState  
  92. 在将 varchar 值 'kk' 转换成数据类型 int 时失败。  16      1  
  93. */  
  94.   
  95.   
  96. -----------------------------------------------------  
  97. -----------------------------------------------------  
  98.   
  99. --  【案例4：解决方案】  
  100.   
  101. BEGIN TRAN   
  102. BEGIN TRY  
  103.     INSERT INTO AA SELECT 1         --A处  
  104.     EXEC('INSERT INTO #BB SELECT 1')--B处  
  105.     COMMIT TRAN;  
  106. END TRY  
  107. BEGIN CATCH  
  108.     SELECT ERROR_MESSAGE() AS ErrorMessage  
  109.     ,ERROR_SEVERITY() AS ErrorSeverity  
  110.     ,ERROR_STATE() AS ErrorState  
  111.     ROLLBACK TRAN;  
  112. END CATCH  
  113.   
  114. /*正常捕获异常！  
  115.   
  116. 不报之前错误：对象名 '#BB' 无效。  
  117.   
  118. 但要求格式为：EXEC(@sql)  
  119. */  
  120.   
  121. -----------------------------------------------------  
  122. -----------------------------------------------------  
  123.   
  124. --  【案例5：解决方案】  
  125. SET XACT_ABORT ON  
  126. BEGIN TRAN   
  127. BEGIN TRY  
  128.     INSERT INTO AA SELECT 1     --A处  
  129.     INSERT INTO #BB SELECT 1    --B处  
  130.     COMMIT TRAN;  
  131. END TRY  
  132. BEGIN CATCH  
  133.     SELECT ERROR_MESSAGE() AS ErrorMessage  
  134.     ,ERROR_SEVERITY() AS ErrorSeverity  
  135.     ,ERROR_STATE() AS ErrorState  
  136.     ROLLBACK TRAN;  
  137. END CATCH  
  138. SET XACT_ABORT OFF  
  139.   
  140.   
  141. /*运行结果：  
  142.   
  143.   
  144. (1 行受影响)  
  145. 消息 208，级别 16，状态 0，第 5 行  
  146. 对象名 '#BB' 无效。  
  147.   
  148. 报错，但是事务会自动回滚.  
  149. 系统默认： SET XACT_ABORT OFF  
  150. 当 SET XACT_ABORT 为 ON 时，如果执行 Transact-SQL 语句产生运行时错误，则整个事务将终止并回滚。  
  151. */  
  152.   
  153.   
  154. --查看 XACT_ABORT 是否打开  
  155. SELECT (CASE WHEN (16384 & @@OPTIONS) = 16384 THEN 'ON' ELSE 'OFF' END) AS XACT_ABORT;  
  156.   
  157.   
  158. /*  
  159.   
  160. 1. 轻微错误（严重性级别为0-10）：默认情况下不会给客户程序发送错误消息，继续工作。也就是说它无法被CATCH到  
  161.   
  162. 2. 中等错误（严重性级别为11-19）：能够被CATCH到（不管是在T-SQL里面还是在客户程序里面）  
  163.   
  164. 3. 严重错误（严重性级别为20-25）：SQL Server将强制把连接关掉。很显然这也不可能被CATCH到  
  165.   
  166.   
  167. 【重点提示！！】  
  168.   
  169. 由于业务的复杂或者系统性能问题，致使数据库sql语句执行较久。  
  170.   
  171. 导致客户端网页已经连接超时（如设置为30秒）  
  172.   
  173. 此时数据库批处理语句未执行完成，客户session断开，相当于中断操作，类似【案例1】的中断。  
  174.   
  175. 事务是没有提交或回滚的，资源仍在占用，导致发生堵塞或死锁！~  
  176.   
  177.   
  178.   
  179. 【解决方法】：  
  180.   
  181. 在批处理语句前加上 SET XACT_ABORT ON  
  182. 当客户端中断的时候，未执行完成则回滚操作，及时释放资源。  
  183.   
  184. */ 
【推广】 免费学中医，健康全家人
原文地址：https://www.cnblogs.com/lykbk/p/feefeererer454545454554.html