学习记录：用netlogo6.1.1创建完整的模型

1.创建新模型

2.创建按钮

先做一个setup按钮，用来重置模型：

to setup ;;;定义一个名为setup的代码
  clear-all ;;;将世界设为初始状态，为新模型运行做好准备
  create-turtles 100 [ setxy random-xcor random-ycor ];;;有100个个体，它们接受观察者写在[]里的命令：返回任意一个x坐标，和任意一个y坐标，个体移动到这个位置
  reset-ticks ;;;重置时间步
end

回到界面，发现setup已经变黑，说明已经写了代码，点击运行

出现了很多彩色的小箭头，它们就代表我们创建的100个个体，而且多点几次setup会发现每次彩色箭头的分布都不一样。

有了setup，还需有go按钮，go表示让模型动起来，前几步步骤同上，主要代码不一样，而且需要在编辑对话框里勾选持续运行：

因为setup只是用来重置，它一次就可完成，不需要持续运行；而go是一个当你点击后就不会主动停下来的键，也就是控制世界的运行的开关键。

现在开始写go的代码：

to go
  move-turtles
  tick
end

这里的move-turtles是我们接下来要定义的语句，它可以看做是一个函数，我们要定义一个move-turtles函数，让它来决定个体如何移动

to move-turtles
  ask turtles [
    right random 360
    forward 1
  ]
end

这个代码让个体，从0-360任选一个实数，然后向右偏转该角度，并且前进一格。现在这个模型已经可以运转了，回到界面，先点击setup，再点击go，观察一下发生了什么事

然后我们考虑羊吃草那个模型，把背景看做是草地，羊会吃掉草，草也会生长，现在需要修改一下模型的代码：

to go
  move-turtles
  eat-grass
  tick
end

to move-turtles
  ask turtles [
    right random 360
    forward 1
    set energy energy - 1
  ]
end

to eat-grass
  ask turtles [
    if pcolor = green [
      set pcolor black
      set energy energy + 10
    ]
  ]
end

可以看见，go中多了一个新函数eat-grass，eat-grass做的事情是，如果个体背景pcolor的颜色是绿色，也就是羊来到了它脚下的一小块草地，那么这块草地会被吃光，吃光了的草地用黑色表示；然后羊自身的能量也会增加，因为吃饱了，增加多少呢，增加10。

同时羊在走的时候也会消耗能量，所以原先的move-turtles函数也需要修改，每走一步，就降低1个能量。

因为energy这个特征是新定义的，原来的个体没有这个energy，所以需要在所有代码的最前端先设定一下：

turtles-own[energy]

羊吃草全代码如下，现在已经可以运行这个羊吃草的模型了：

turtles-own[energy]


to setup
  clear-all
  setup-patches
  setup-turtles
  reset-ticks
end

to setup-patches
  ask patches [set pcolor green ]
end

to setup-turtles
  create-turtles 100 [ setxy random-xcor random-ycor ]
end


to go
  move-turtles
  eat-grass
  tick
end

to move-turtles
  ask turtles [
    right random 360
    forward 1
    set energy energy - 1
  ]
end

to eat-grass
  ask turtles [
    if pcolor = green [
      set pcolor black
      set energy energy + 10
    ]
  ]
end