为CGridHelper增加合并单元格的能力

一、关于起因

昨天刚刚完成了CGridHelper的部分代码,今天的需求就变动了,需要为这个类添加合并单元格内容的能力。DataGridView控件本身没有提供这个功能,需要自己写代码实现。首先想到的是拿来主义，网上搜罗了一下，找了段C#代码，翻译成Vb.net之后呈现给大家。最终实现的效果如下图所示：

二、CGridHelper新的调用代码

        Dim mGridHelper As New CGridHelper(GridVersion, Color.FromArgb(250, 250, 250),
            New Font("微软雅黑", 10), 30, Color.FromArgb(159, 210, 235), Color.FromArgb(0, 0, 0), 24,
            New Font("微软雅黑", 9), 30, Color.FromArgb(250, 250, 250), Color.FromArgb(225, 225, 225), Color.FromArgb(0, 0, 0),
            "0;80;70;595", "M;M;M;L", "1;2")

新的调用通过最后一个MergeColumn字符串参数设置,将需要合并的列号以逗号进行分隔。

三、CGridHelper变动部分代码

    Private WithEvents mGrid As DataGridView

    Private mMergeColumn As String
    Public Property MergeColumn() As String
        Get
            Return mMergeColumn
        End Get
        Set(ByVal value As String)
            mMergeColumn = value
        End Set
    End Property

    Private Function GetMergeComumns() As List(Of Integer)
        If Me.MergeColumn Is Nothing OrElse Me.MergeColumn.Length = 0 Then Return Nothing
        Dim mCol As List(Of String) = Me.MergeColumn.Split(";").ToList
        Dim rtl As New List(Of Integer)
        For Each str As String In mCol
            On Error Resume Next
            rtl.Add(CType(str, Integer))
        Next
        Return rtl
    End Function

    Private Sub mGrid_CellPainting(sender As Object, e As DataGridViewCellPaintingEventArgs) Handles mGrid.CellPainting
        Dim mCols As List(Of Integer) = Me.GetMergeComumns()
        If mCols Is Nothing OrElse mCols.Count = 0 Then Exit Sub
        If e.RowIndex = -1 Then Exit Sub
        If Not mCols.Exists(Function(v As Integer) v = e.ColumnIndex) Then Exit Sub
        Using gridBrush As New SolidBrush(Me.Grid.GridColor), backColorBrush As New SolidBrush(e.CellStyle.BackColor)
            Using gridLinePen As New Pen(gridBrush)
                e.Graphics.FillRectangle(backColorBrush, e.CellBounds)  '//清除单元格
                '// 画 Grid 边线（仅画单元格的底边线和右边线）
                '// 如果下一行和当前行的数据不同，则在当前的单元格画一条底边线
                If e.RowIndex < Me.Grid.Rows.Count - 1 AndAlso
                    Me.Grid.Rows(e.RowIndex + 1).Cells(e.ColumnIndex).Value.ToString <> e.Value.ToString Then
                    e.Graphics.DrawLine(gridLinePen, e.CellBounds.Left, e.CellBounds.Bottom - 1, e.CellBounds.Right - 1, e.CellBounds.Bottom - 1)
                End If
                '//画最后一条记录的底线 
                If e.RowIndex = Me.Grid.Rows.Count - 1 Then
                    e.Graphics.DrawLine(gridLinePen, e.CellBounds.Left + 2, e.CellBounds.Bottom - 1, e.CellBounds.Right - 1, e.CellBounds.Bottom - 1)
                End If
                '//画右边线
                e.Graphics.DrawLine(gridLinePen, e.CellBounds.Right - 1, e.CellBounds.Top, e.CellBounds.Right - 1, e.CellBounds.Bottom)
                '// 画（填写）单元格内容，相同的内容的单元格只填写第一个
                If Not e.Value Is Nothing Then
                    If Not (e.RowIndex > 0 AndAlso Me.Grid.Rows(e.RowIndex - 1).Cells(e.ColumnIndex).Value.ToString = e.Value.ToString) Then
                        e.Graphics.DrawString(e.Value, e.CellStyle.Font, Brushes.Black, e.CellBounds.X + 2, e.CellBounds.Y + 5, StringFormat.GenericDefault)
                    End If
                    e.Handled = True
                End If
            End Using
        End Using
    End Sub