1304: [CQOI2009]叶子的染色

Description
给一棵m个结点的无根树，你可以选择一个度数大于1的结点作为根，然后给一些结点（根、内部结点和叶子均可）着以黑色或白色。你的着色方案应该保证根结点到每个叶子的简单路径上都至少包含一个有色结点（哪怕是这个叶子本身）。 对于每个叶结点u，定义c[u]为从u到根结点的简单路径上最后一个（应该是最深的那个吧）有色结点的颜色。给出每个c[u]的值，设计着色方案，使得着色结点的个数尽量少。
Input
第一行包含两个正整数m, n，其中n是叶子的个数，m是结点总数。结点编号为1，2，…，m，其中编号1，2，… ，n是叶子。以下n行每行一个0或1的整数（0表示黑色，1表示白色），依次为c[1]，c[2]，…，c[n]。以下m-1行每行两个整数a，b（1<=a < b <= m），表示结点a和b 有边相连。
Output
仅一个数，即着色结点数的最小值。
Sample Input
5 3
0
1
0
1 4
2 5
4 5
3 5
Sample Output
2
HINT

M<=10000
N<=4996

不知道为什么有这么一个结论，任何一个合法节点做根答案都不变（）

然后树dp之

每个节点都有三个状态，这棵子树的叶子全部满足，这棵子树的叶子只剩下0没有满足，这棵子树的叶子只剩下1没有满足

然后yy一下就可以想出来转移方程了

叶子全部满足就是

1.什么都不做，下面都满足了

2.只有0或者只有1没有满足，把这个节点染成0或1

只剩下0没有满足就是子树全部满足或者只剩下0没有满足

只剩下1没有满足就是子树全部满足或者只剩下1没有满足

const
    maxn=10010;
var
    first,c:array[0..maxn]of longint;
    next,last:array[0..maxn*2]of longint;
    f:array[0..maxn,0..2]of longint;
    flag:array[0..maxn]of boolean;
    n,m,tot:longint;

procedure insert(x,y:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;

function min(x,y:longint):longint;
begin
    if x<y then exit(x);
    exit(y);
end;

procedure dfs(x:longint);
var
    i,s0,s1,s2:longint;
begin
    flag[x]:=true;
    if x<=n then
    begin
      f[x,0]:=1;
      f[x,c[x]+1]:=0;
      f[x,2-c[x]]:=1;
      exit;
    end;
    i:=first[x];
    s0:=0;
    s1:=0;
    s2:=0;
    while i<>0 do
      begin
        if flag[last[i]]=false then
        begin
          dfs(last[i]);
          inc(s0,f[last[i],0]);
          inc(s1,min(f[last[i],1],f[last[i],0]));
          inc(s2,min(f[last[i],2],f[last[i],0]));
        end;
        i:=next[i];
      end;
    f[x,0]:=min(s0,min(s1+1,s2+1));
    f[x,1]:=s1;
    f[x,2]:=s2;
end;

procedure main;
var
    i,x,y:longint;
begin
    read(m,n);
    for i:=1 to n do
      read(c[i]);
    for i:=1 to m-1 do
      begin
        read(x,y);
        insert(x,y);
        insert(y,x);
      end;
    dfs(m);
    writeln(f[m][0]);
end;

begin
    main;
end.